书籍是全世界的营养品。生活里没有书籍，就好像没有阳光；智慧里没有书籍，就好像鸟儿没有翅膀。
Delphi提供的所有控件(Control，即能获得输入焦点的部件)都支持拖放操作，并有相应的拖放属性、拖放事件和拖放方法。下面我们先介绍控件的拖放支持，而后再给出开发拖放操作的一般步骤和应用实例。
9.1 控件的拖放支持
拖放操作中控件可以分为源控件和目标控件两类。绝大部分控件既可以作为源控件也可以作为目标控件。但也有一部分控件只能支持其中的一种。
9.1.1 拖放属性
拖放属性主要有两个：
● DragMode ： 拖动模式
● DragCursor ： 拖动光标
它们都是在拖放的源控件中设置。DragMode控制用户在运行时间内当在控件上按下鼠标时控件如何反应。如果DragMode置为dmAutomatic，那么当用户在控件上按下鼠标时拖动自动开始；如果DragMode置为dmManual(这是缺省值)，则将通过处理鼠标事件来判断一个拖动是否可以开始。
DragCursor用于选择拖动时显示的光标，缺省值是CrDrag，一般不要去修改它。在程序设计过程中通用的界面规范应该得到开发者的尊重。但有时候为了特定的目的，开发者也可以把自己设计的光标赋给DragCursor。
9.1.2 拖放事件
拖放事件主要有三个：
●OnDragOver：拖动经过时激发
●OnDragDrop：拖动放下时激发
●OnEndDrop ：拖动结束时激发
前两个事件由目标控件响应，后一个事件由源控件响应。
OnDragOver事件最主要的功能是确定当用户就地放下拖动时控件是否可以接受。它的参数包括：
Source ： TObject； {源控件}
X，Y ： Integer; {光标位置}
State ： TDragState； {拖动状态}
var Accept ： Boolean {能否接受}
TDragState是一个枚举类型，表示拖放项目与目标控件的关系。
type
TDragState = (dsDragEnter, dsDragLeave, dsDragMove);
不同取值的意义如下表：
表9.1 DragState 的取值与意义
━━━━━━━━━━━━━━━━━━━━━━━━━━━
取 值 意 义
───────────────────────────
dsDragEnter 拖动对象进入一个允许拖动对象放下
的控件中。为缺省状态。
dsDragLeave 拖动对象离开一个允许拖动对象放下
的控件。
dsDragMove 拖动对象在一个允许拖动对象放下的
控件内移动。
━━━━━━━━━━━━━━━━━━━━━━━━━━━
用户可以利用提供的参数来确定放下的拖动是否可被接受，如：
● 判断源控件类型：
Accept := Source is TLabel;
●
判断源控件对象：Accept := (Source = TabSet1);
●
判断光标位置：见(9.2),(9.3)中的例程。
● 判断拖动状态：
If (Source is TLabel) and (State = dsDragMove) then
begin
source.DragIcon := ' New.Ico ';
Accept := True;
end
else
Accept := False;
当
Accept=True时，目标控件可以响应OnDragDrop事件，用于确定拖动被放下后程序如何进行处理。OnDragDrop事件处理过程的参数包括源控件和光标位置。这些信息可用于处理方式的确定。
OnEndDrag事件是在拖动操作结束后由源控件来进行响应的，用于源控件进行相应的处理。拖动操作结束既包括拖动放下被接受，也包括用户在一个不能接受放下的控件上释放了鼠标。该事件处理过程的参数包括目标控件(Target)和放下位置的坐标。如果Target=nil, 表示拖动项目没有被任何控件接受。
在第
3节将介绍的文件拖放移动、拖放拷贝操作中，如果操作成功，则文件列表框应更新显示内容。下面这段程序用于实现这一功能。procedure TFMForm.FileListEndDrag(Sender, Target: TObject; X, Y: Integer);
begin
if Target <> nil then FileList.Update;
end;
除以上介绍的三个事件外，还有一个事件
OnMouseDown 也常用于拖放操作的响应。OnMouseDown虽然不是一个专门的拖放事件，但在人工模式下拖动的开始是在这一事件的处理过程中实现的。9.1.3 拖放方法
拖放方法有三个：
●BeginDrag ： 人工方式下开始一个拖动
●EndDrag ： 结束一个拖动
●Dragging ： 判断一个控件是否正被拖动
这三个方法都被源控件使用。
当DragMode置为dmManual时，拖动必须调用控件的BeginDrag方法才能开始。BeginDrag有一个布尔参数Immediate。如果输入参数为True，拖动立即开始，光标改变到DragCursor的设置。如果输入参数为False，直到用户将光标移动了一定的距离(5个象素点)后才改变光标，开始拖动。这就允许控件接受一个OnClick事件而并不开始拖动操作。
EndDrag方法中止一个对象的被拖动状态。它有一个布尔参数Drop。如果Drop设置为True，被拖动的对象在当前位置放下(能否被接受由目标控件决定)；如果Drop设置为False，则拖动就地被取消。
下面一段程序表明当拖动进入一控制面板时拖动被取消。
procedure TForm1.Panel1DragOver(Sender, Source: TObject; X, Y: Integer;
State: TDragState; var Accept: Boolean);
begin
Accept := False;
if (Source is TLabel) and (State = dsDragEnter) then
(Source as TLabel).EndDrag(False);
end;
Draging方法判断一个控件是否正被拖动。在下面的例子中当用户拖动不同的检查框时窗口改变为不同的颜色。
procedure TForm1.FormActivate(Sender: TObject);
begin
CheckBox1.DragMode := dmAutomatic;
CheckBox2.DragMode := dmAutomatic;
CheckBox3.DragMode := dmAutomatic;
end;
procedure TForm1.FormDragOver(Sender, Source: TObject; X, Y: Integer;
State: TDragState; var Accept: Boolean);
begin
if CheckBox1.Dragging then
Color := clAqua;
if CheckBox2.Dragging then
Color := clYellow;
if CheckBox3.Dragging then
Color := clLime;
end;
9.2 开发拖放功能的一般步骤
拖放作为Windows提供的一种方便操作对象的功能，在Delphi中可以很容易地开发出来。根据拖放操作的过程可以把开发步骤划分为四个阶段，即：
● 开始拖动操作
● 接收拖动项目
● 放下拖动项目
● 终止拖动操作
在介绍过程中我们将结合一个TabSet(标签集)的拖放操作实例。界面设计如图。在运行时当用户把一个标签拖动到另一个标签的位置时，该标签将移动到该位置并引起标签集的重新布置。
9.2.1 开始拖动操作
当拖动模式(DragMode)设置为dmAutomatic时，用户在源控件上按下鼠标时拖动自动开始；当设置为dmManual时通过处理鼠标事件来决定拖动是否开始。如果想开始拖动调用BeginDrag方法。
在TabSet拖放中，我们用下面的MouseDown事件处理过程来开始一个标签的拖动。首先判断按下的是否是左键，而后再判断项目是否合法。
procedure TForm1.TabSet1MouseDown(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
var
DragItem: Integer;
begin
if Button = mbLeft then
begin
DragItem := TabSet1.ItemAtPos(Point(X, Y));
if (DragItem > -1) and (DragItem < TabSet1.Tabs.Count) then
TabSet1.BeginDrag(False);
end;
end;
9.2.2 接收拖动项目
一个控件能否接收拖动项目是由该控件的OnDragOver事件决定的。在TabSet拖动中，主要是利用鼠标的位置进行判断。
procedure TForm1.TabSet1DragOver(Sender, Source: TObject; X, Y: Integer;
State: TDragState; var Accept: Boolean);
var
DropPos: Integer;
begin
if Source = TabSet1 then
begin
DropPos := TabSet1.ItemAtPos(Point(X, Y));
Accept := (DropPos > -1) and (DropPos <> TabSet1.TabIndex) and
(DropPos < TabSet1.Tabs.Count);
end;
else
Accept := False;
end;
9.2.3 放下拖动项目
当
OnDragOver事件处理过程返回的Accept为True且项目被放下时，由OnDragDrop事件处理过程来完成拖动放下后的响应。在TabSet拖放实例中是改变标签的位置。procedure TForm1.TabSet1DragDrop(Sender, Source: TObject; X, Y: Integer);
var
OldPos: Integer;
NewPos: Integer;
begin
if Source = TabSet1 then
begin
OldPos := TabSet1.TabIndex;
NewPos := TabSet1.ItemAtPos(Point(X, Y));
if (NewPos > -1) and (NewPos <> OldPos) then
TabSet1.Tabs.Move(OldPos, NewPos);
end;
end;
9.2.4 结束拖动操作
结束拖动操作的方式有两种：或者是用户释放了鼠标键或者是程序用EndDrag方法强行中止拖动。结束拖动操作的后果有两种：放下被接受或放下被忽略。
拖动操作结束后源控件都要收到一条消息响应拖动结束事件OnEndDrag。
9.3 拖放应用实例：文件管理器的拖放支持
在第六章最后开发的文件管理器应用实例，虽然功能上已初具规模，但在操作上与Windows的文件管理器相比还有很大不足。其中最大的缺陷是它不支持文件的拖放移动和拖放拷贝。在这一章结束的时候，我们可以来弥补这一缺陷了。
文件拖放移动指的是当用户把一个文件拖动到目录树下的某一目录并放下时，文件将自动移动到该目录中；文件拖放拷贝指的是当用户把一个文件拖动到某个驱动器标签上并放下时，文件将自动拷贝到该驱动器的当前目录下。作为源控件的文件列表框和作为目标控件的目录树、驱动器标签可以位于不同的子窗口。驱动器的当前目录是任一子窗口的最新操作结果，而不论这一子窗口与拖动源、拖动目标是否有关系。
为了实现上述功能，有两个问题必须首先解决：
1.如何记录每一驱动器的当前目录？
为此我们定义了一个全局变量：
var
CurentDirList: Array[0...25] of string[70];
在DirectoryOutline的OnChange事件中：
procedure TFMForm.DirectoryOutlineChange(Sender: TObject);
begin
CreateCaption;
FileList.clear;
FileList.Directory := DirectoryOutline.Directory;
FileList.Update;
CurrentDirList[DriveTabSet.TabIndex] := DirectoryOutline.Directory;
FileManager.DirectoryPanel.Caption := DirectoryOutline.Directory;
end;
由于DriveTabSet在响应OnDragDrop事件前先响应OnClick事件，并由该事件激发DirectoryOutline的Onchange事件，因而可保证在任何时候OnDragDrop事件中用到的CurrentDirList数组项不为空字符串。
2.如何保证移动、拷贝与子窗口的无关性？
在这里一个关键问题是我们判断源控件时是用is操作符进行类型检查:
If Source is TFileList then
…
如果我们用下面的语句：
If Source = FileList then
…
则移动、拷贝操作将限制在本子窗口范围内。
当解决了上述问题后我们的工作就只是遵循拖放的一般开发步骤，按步就班来完成了。
1.FileList开始拖动操作
procedure TFMForm.FileListMouseDown(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
if Button = mbLeft then
with Sender as TFileListBox do
begin
if ItemAtPos(Point(X, Y), True) >= 0 then
BeginDrag(False);
end;
end;
ItemAtPos用来检查当前是否有文件存在。而BeginDrag方法传递参数False, 允许FileList单独处理鼠标事件而并不开始拖动。事实上这种情况是大量存在的。
2.DirectoryOutline、DriveTabSet决定是否能接受拖动的就地放下。
procedure TFMForm.DirectoryOutlineDragOver(Sender, Source: TObject; X,
Y: Integer; State: TDragState; var Accept: Boolean);
begin
if Source is TFileListBox then
Accept := True;
end;
procedure TFMForm.DriveTabSetDragOver(Sender, Source: TObject; X,
Y: Integer; State: TDragState; var Accept: Boolean);
var
PropPos: Integer;
begin
if Source is TFileListBox then
with DriveTabSet do
begin
PropPos := ItemAtPos(Point(X,Y));
Accept := (PropPos > -1) and (PropPos < Tabs.Count);
end;
end;
DirectoryOutline是无条件的接受，而DriveTabSet需检查是否是合法的标签。
3.拖动放下的响应
DirectoryOutline的拖动放下用于实现文件移动功能。程序中调用ConfirmChange事件处理过程，目标路径由DirctoryOutline.Items[GetItem(X,Y)].FullPath来得到。
procedure TFMForm.DirectoryOutlineDragDrop(Sender, Source: TObject; X,
Y: Integer);
begin
if Source is TFileListBox then
with DirectoryOutline do
begin
ConfirmChange('Move',FileList.FileName, Items[GetItem(X, Y)].FullPath);
end;
end;
DriveTabSet的拖动放下用于实现文件拷贝功能。程序中把当前位置转化为相应的驱动器号，目标路径由CurrentDirList[DriveTabSet.TabIndex]获得。
procedure TFMForm.DriveTabSetDragDrop(Sender, Source: TObject; X,Y: Integer);
var
APoint: TPoint;
begin
APoint.X := X; APoint.Y := Y;
DriveTabSet.TabIndex := DriveTabSet.ItemAtPos(APoint);
if Source is TFileListBox then
with DriveTabSet do
begin
if CurrentDirList[TabIndex] <> '' then
ConfirmChange('Copy',TheFilename,CurrentDirList[TabIndex]);
end;
end;
4.FileList响应拖动结束，更新文件列表
procedure TFMForm.FileListEndDrag(Sender, Target: TObject; X, Y: Integer);
begin
if Target <> nil then FileList.Update;
end;
到目前为止，我们的文件管理器功能已足够强大。 不过还有许多问题值得读者去进
一步探讨，如：
1.文件与应用程序关联的建立；
2.在文件列表框中显示更多的文件信息；
3.文件列表框中的文件按后缀各排序等。
文件管理器是一个真正的综合例程，对它的钻研会使您更进一步模到Delphi编程的精髓。
